Командные файлы Windows


Предыдущая | Следующая

Общие сведения о командном процессоре Windows.

Использование переменных в командных файлах.

Передача параметров командному файлу.

Переходы и метки.

Примеры командных файлов:

    - Своя команда для создания новых файлов.

    - Присвоение съемному диску одной и той же буквы.

    - Создание архива, имя которого содержит дату и время.

    - Выполнение только в заданный интервал времени.

    - Пример создания архива каталога пользователя.

    - Изменение даты и времени для файлов и папок.

    - Выполнение команд по расписанию.

    - Запуск и остановка служб Windows в командной строке.

    - Выдача на экран значения ERRORLEVEL.

    - Диалог с пользователем.

    - Задержки в командных файлах.

    - Определение доступности IP-адреса.

    - Определение текущей версии Windows.

    - Поиск в локальной сети компьютеров с запущенным приложением.

    - Поиск компьютеров с запущенным приложением по списку на основе сетевого окружения.

    - Выключение компьютеров по списку, созданному на основе сетевого окружения.

    - Поиск в локальной сети включенных компьютеров.

    - Работа с дисками, файлами и каталогами.

    - Работа с графическими приложениями из командной строки.

    - Перекодировка текстовых файлов .

    - Часто встречающиеся ошибки при написании командных файлов.

    - Использование .bat и .cmd в сценариях регистрации пользователей.

 

Общие сведения о командном процессоре Windows.



    Командные файлы (пакетные файлы, скрипты, сценарии, ”батники”) - это обычные текстовые файлы с расширением .bat или .cmd, строки которых представляют собой специальные команды командного процессора (интерпретатора команд ) и/или имена исполняемых файлов с параметрами. Командный процессор – это специальная программа, являющаяся обязательным элементом практически любой операционной системы, главным назначением которой, является предоставление пользователю возможности выполнения определенных программ без их компиляции и создания исполняемых файлов. Для операционных систем DOS и Windows9X в качестве интерпретатора команд использовался командный процессор command.com, для всех остальных ОС семейства Windows ( NT/2k/XP/Vista/7/8/10 и старше) -cmd.exe. 

Несмотря на непрерывное совершенствование средств создания и выполнения сценариев с использованием объектно-ориентированных языков, обычная командная строка и простые командные файлы, по-прежнему остаются основным инструментом для выполнения рутинных действий, диагностики сетевых проблем, автоматизации процессов резервного копирования и т.п. При всех недостатках реализации командного процессора в Windows, достойной альтернативы ему нет, и очевидно в ближайшем будущем, не будет. 

    Как уже упоминалось выше, командный файл – это обычный текстовый файл с набором команд, которые последовательно выполняются командным процессором CMD Windows. Строки командных файлов могут содержать специфические команды самого процессора команд (FOR, ECHO, REM и т.п.) или имена исполняемых модулей (net.exe, regedit.exe, sc.exe) Командный процессор может быть запущен в интерактивном режиме через Пуск - Выполнить - CMD.EXE. В данном режиме, вы увидите окно CMD.EXE ( консоли ) с приглашением к вводу команд. Возможный список большинства консольных команд можно получить введя команду:

HELP
Справочную информацию по конкретной команде можно получить, указав ее название в качестве параметра команды HELP:

HELP Имя команды 

Если вы работаете в русифицированной версии Windows, то учтите, что в среде командного процессора символы национального алфавита используются в DOS-кодировке. Для переключения между кодовыми страницами Windows и DOS используется команда 

CHCP номер страницы
CHCP 866 - использовать кодовую страницу 866 (DOS)
CHCP 1251 - использовать кодовую страницу 1251 (WINDOWS) 

Для просмотра и редактирования командных файлов, содержащих символы русского алфавита нужно использовать редактор с поддержкой DOS-кодировки. Если вы используете стандартное приложение "Блокнот" (notepad.exe), то для правильного отображения символов русского алфавита нужно выбрать шрифт Terminal, с помощью меню Правка - Шрифт... 

Внешний вид окна CMD.EXE (консоли Windows) можно изменить с помощью команды 

COLOR 

В качестве аргументов для команды используются 2 шестнадцатеричные цифры, задающие цвет фона и цвет символа. 

COLOR F0 - символы белого цвета на черном фоне (используется по умолчанию).

COLOR F0 - черные символы на белом фоне.

COLOR 0E - светло-желтые символы на черном фоне.

HELP COLOR - подсказка для команды COLOR. 

Работа с командным процессором предполагает использование двух стандартных устройств - устройства ввода (клавиатуры) и устройства вывода (дисплей). Однако, имеется возможность изменить стандартно используемые устройства ввода-вывода с помощью специальных символов - символов перенаправления 

> - перенаправление вывода 
< - перенаправление ввода

Для вывода справки не на экран а, например, в файл с именем help.txt, можно использовать следующую команду:

HELP > help.txt 
При выполнении данной команды, в текущем каталоге будет создан файл с именем help.txt, содержимым которого будет результат вывода команды HELP. Если файл help.txt существовал на момент выполнения команды, его содержимое будет перезаписано. Для того, чтобы дописать данные в конец существующего файла, используют удвоение символа перенаправления вывода - ">>" 

Пример:

HELP GOTO > myhelp.txt - в файл myhelp.txt будет выдана справка по использованию команду GOTO
HELP COLOR >> myhelp.txt - в конец файла myhelp.txt будет дописана справка по использованию команды COLOR

Простейший пример перенаправления ввода:

cmd.exe < commands.txt - командный процессор не будет ожидать ввода команд с клавиатуры, а считает их из файла commands.txt. Фактически, указанный текстовый файл в данном случае является командным файлом.

    При запуске командного процессора можно указать конкретную команду в качестве аргумента командной строки: 

cmd.exe /C HELP FOR - выполнить команду HELP FOR и завершиться (параметр командной строки или ключ /C) 

cmd.exe /K HELP FOR - выполнить команду HELP FOR и перейти в режим ожидания дальнейшего ввода команд (ключ /K)

Подробную справку по использованию cmd.exe можно получить, введя в качестве аргумента ключ /?

cmd.exe /? 

Кроме символов перенаправления ввода-вывода в командной строке могут использоваться символы объединения команд - & (амперсанд) и |(вертикальная черта)

& - одиночный амперсанд используется для разделения нескольких команд в одной командной строке. 

команда1 & команда2 - выполняется первая команда, затем вторая команда.

&& - условное выполнение второй команды. Она будет выполнена, если код завершения (или код возврата) первой команды равен нулю, т.е. команда выполнена успешно. Успешность выполнения команды определяется значением специальной переменной среды ERRORLEVEL.

команда1 && команда2 - выполняется команда1, а команда2выполняется, только если первая была выполнена успешно.

|| - условное выполнение второй команды. Если первая команда завершилась с кодом возврата не равным нулю (неуспешно), то выполняется команда, следующая за двойной вертикальной чертой.

команда1 || команда2 - если команда1 выполнена неуспешно, то запускается на выполнение команда2

Команду, следующую после знаков объединения, не нужно заключать в двойные кавычки, иначе командный процессор удвоит их и сообщит об ошибке. Выполнение командной строки 

cmd.exe /C "HELP IF" & ”HELP IF”

Завершится выполнением первой команды и сообщением об ошибке для второй: 

""HELP" не является внутренней или внешней командой, исполняемой программой или пакетным файлом.



Файлы с расширением .bat или .cmd в среде Windows стандартно открываются командным процессором аналогично рассмотренному выше примеру с перенаправлением ввода, когда последовательность команд считывается не с устройства ввода, а из текстового файла. 

 

 



 

Использование переменных в командных файлах.



    При работе с командными файлами, очень важное значение имеет такой инструмент как переменные окружения (environments) - переменные, значения которых определяют среду, в которой выполняются команда или пакетный файл. Иногда их называют переменными среды. Значения, принимаемые этими переменными формируются при загрузке Windows, регистрации пользователя в системе, старте или завершении некоторых приложений, и, кроме того, могут быть заданы с помощью специальной команды SET

SET переменная=строка 

переменная - имя переменной среды.
строка - строка символов, присваиваемая указанной переменной.

Например, командная строка
SET myname=Vasya
создает переменную myname, принимающую значение Vasya. 

Значение, присвоенное какой-либо переменной, доступно для обработки в командной строке или в командном файле с использованием ее имени, заключенного в знаки процента - % . Наглядный пример - команда выдачи текста на дисплей ECHO в виде:
ECHO date - выведет на экран слово "date", а команда 
ECHO %date% выведет на экран значение переменной date - текущую дату в формате операционной системы.

Грамотное использование стандартных переменных окружения позволяют создавать командные файлы, которые будут одинаково выполняться на разных компьютерах, независимо от их конкретной конфигурации и пользовательских настроек. На практике, с помощью команды SET обычно задается и модифицируется путь поиска исполняемых программ - переменная окружения PATH. 

SET PATH=C:\Windows;C:\windows\system32 
После выполнения данной команды, поиск исполняемых файлов будет выполняться в каталоге C:\Windows, и, если результат неуспешен, вC:\windows\system32

При необходимости выполнить программу, например, myedit.exe, размещенную в каталоге C:\NewProgs необходимо либо указать полный путь исполняемого файла, либо сделать текущим каталогом каталог с программой и использовать только его имя. Если в командной строке не задан полный путь, а только имя исполняемого файла - myedit.exe то сначала будет выполняться поиск файла myedit.exe в текущем каталоге, и если он не будет найден - в каталогах, список которых определяется значением переменной PATH. Символ ; является разделителем элементов в списке путей поиска. Если в приведенном примере, текущим каталогом не является C:\NewProgs, и в остальных каталогах, заданных значением переменной PATH. нет исполняемого файла myedit.exe, то запуск приложения myedit.exe завершится ошибкой. Однако, если модифицировать значение переменной PATH, добавив в нее требующийся каталог, то указание полного пути исполняемого файла становится необязательным. Команда 

SET PATH=C:\NewProgs;%path% 
изменит текущее значение PATH, добавив каталог C:\NewProgs в начало списка. Для добавления каталога в конец списка используется несколько иная конструкция: 

SET PATH=%path%;C:\NewProgs


    Выполнение команды SET без параметров позволяет получить текущие значения переменных окружения:
 

NUMBER_OF_PROCESSORS=1 - количество процессоров

OS=Windows_NT- тип ОС

Path=C:\WINDOWS\system32;C:\WINDOWS;C:\Program Files\Far - путь поиска исполняемых файлов.

PATHEXT=.COM;.EXE;.BAT;.CMD;.VBS;.VBE; .JS;.JSE;.WSF;.WSH - расширения для исполняемых файлов.

PROCESSOR_ARCHITECTURE=x86 - архитектура процессора.

PROCESSOR_IDENTIFIER=x86 Family 6 Model 8 Stepping 1, AuthenticAMD - идентификатор процессора.

PROCESSOR_LEVEL=6 - уровень (номер модели) процессора.

PROCESSOR_REVISION=0801 - версия процессора.

ProgramFiles=C:\Program Files - путь к папке "Program Files"

PROMPT=$P$G - формат приглашения командной строки $P - путь для текущего каталога $G - знак ">".

SystemDrive=C: - буква системного диска.

SystemRoot=C:\WINDOWS - каталог ОС Windows.



Значения некоторых переменных по команде SET не отображаются, хотя и присутствуют в системе. В основном, это переменные, принимаемые значения которых динамически изменяются: 
 

%CD% - Принимает значение строки текущего каталога.

 

%DATE% - Принимает значение текущей даты.

 

%TIME% - Принимает значение текущего времени.

 

%RANDOM% - Принимает значение случайного десятичного числа в диапазоне 1 -32767.

 

%ERRORLEVEL% - Принимает текущее значение кода завершения задачи ERRORLEVEL

 

%CMDEXTVERSION% - Принимает значение версии командного процессора CMD.EXE для расширенной обработки команд.

 

%CMDCMDLINE% - Принимает значение строки, которая вызвала командный процессор.



Для просмотра текущего значения какой-либо переменной обычно используется команда:

ECHO %переменная%
ECHO %CD% - отобразить имя текущего каталога
ECHO %TIME% - отобразить текущее время
ECHO %ERRORLEVEL% - отобразить значение переменной ERRORLEVEL, специальной переменной, значение которой является индикатором результата выполнения предыдущей команды.

Значения, принимаемые переменными окружения, могут быть расширены с помощью специального признака - символа " ~ ", что позволяет получить их частичное значение, или изменить его подменой какой-либо части. Практические примеры использования расширений переменных будут рассмотрены ниже. 

Значения переменных, установленных командой SET действительны только для текущего сеанса командной строки. Для создания постоянно действующих пользовательских и системных переменных окружения используется специальная команда SetX, позволяющая записывать имена и значения переменных в реестр. Подробное описание команды SetX имеется в разделе Список команд CMD Windows. 

 

Передача параметров командному файлу.



    Очень полезной особенностью работы с командными файлами является возможность получать значения параметров командной строки и использовать их в операциях внутри самого командного файла.

BAT-файл параметр1 параметр2 ... параметрN 
В самом командном файле первый параметр будет доступен как значение переменной %1, второй - %2 и т.п. Путь и имя самого командного файла доступно в качестве значения переменной %0. Для примера создадим командный файл, задачей которого будет выдача на экран значений введенных при его запуске параметров командной строки. Для вывода текста на экран используется команда ECHO текст, однако если "текст" заменить на %0, - то будет выдано имя командного файла, %1 - первый аргумент, заданный в строке запуска, %2 - второй и т.д.
Создаем, например, командный файл params.bat следующего содержания:

echo off echo Это командный файл %0
echo Первый параметр=%1
echo Второй параметр=%2
echo Третий параметр = %3

и запускаем его на выполнение следующей командой:

params.bat FIRST second "two words"

Параметры командной строки, содержащие пробелы должны заключаться в двойные кавычки. 

В первой строке приведенного выше командного файла используется команда echo off, предназначенная для того, чтобы обрабатываемые командным процессором строки не выдавались на экран. 

    При обработке входных параметров необходимо знать, были ли они вообще заданы в командной строке. Для проверки наличия каких-либо входных параметров, передаваемых командному файлу, можно проверить, является ли значение переменной %1 пустым, что можно сделать, заключив ее, например в двойные кавычки, и проверив полученный результат на наличие этих кавычек, следующих подряд:

if "%1" EQU "" goto error
....
... 
:error
Echo Должен быть задан хотя бы один входной параметр
exit

    В командных файлах большого размера трудно обойтись без справочной информации в виде комментариев, для чего используется конструкция 

REM пробел текст 
Строки, начинающиеся с REM пробел, считаются комментариями и командным процессором игнорируются. 

rem ECHO OFF выключает режим вывода содержания строк командного файла на экран
REM будет выводиться только результат их выполнения.
ECHO OFF
echo Первый параметр=%1
echo Второй параметр=%2
echo Третий параметр = %3

Если к имени команды первым символом добавляется @, то независимо от режима ECHO (ON или OFF), вывод обрабатываемой строки не выполняется. Попробуйте в данном примере "ECHO OFF" заменить на "@ECHO OFF" - результат говорит сам за себя. Строка, которая выключает режим вывода, не будет выдаваться на экран. Вывод содержимого обрабатываемых строк ( эхо ) на экран устанавливается по команде ECHO ON и, обычно, используется в целях диагностики.

rem ECHO ON включает режим вывода содержания строк командного файла на экран
REM будет сама командная строка и результат ее выполнения, 
REM но строки, начинающиеся символом @ выводиться не будут ECHO ON
@echo Первый параметр=%1
@echo Второй параметр=%2
@echo Третий параметр = %3


 

Переходы и метки.



    В командных файлах можно использовать команды условного перехода, меняющие логику их работы в зависимости от возникновения определенных условий. В качестве иллюстрации создадим командный файл, целью которого будет присвоение заранее определенной буквы для съемных носителей. Условия таковы - есть 2 съемных диска, один из которых должен быть виден в проводнике как диск X: а второй - как диск Y: независимо от того, в какой порт USB они подключены и какие буквы присвоены им операционной системой. Для примера, будем считать, что реальные диски могут быть подключены как F: или G: Опознавание дисков будем выполнять по наличию файла с определенным именем (лучше всего такой файл сделать скрытым в корневом каталоге съемного диска и назвать его как-нибудь необычно):

Flashd1.let - на первом диске

Flashd2.let - на втором

Таким образом, задача командного файла заключается в том, чтобы проверить наличие на сменных дисках F: и G: файлов Flashd1.let или Flashd2.let и, в зависимости от того, какой из них присутствует, присвоить диску букву X: или Y:

Для поиска файла на диске воспользуемся командой IF EXIST:

IF EXIST имя_файла команда

В качестве команды, которая будет выполнена при удовлетворении условия используем SUBST, которая предназначена для сопоставления каталога и виртуального диска.

SUBST X: C:\ - - создать виртуальный диск X:, содержимым которого будет корневой каталог диска C:


    Для решения поставленной задачи, создаем командный файл, например с именем setletter.bat, следующего содержания:

@ECHO OFF
IF EXIST G:\flashd1.let SUBST X: G:\
IF EXIST F:\flashd1.let SUBST X: F:\
IF EXIST G:\flashd2.let SUBST Y: G:\
IF EXIST F:\flashd2.let SUBST Y: F:\

    После выполнения этого командного файла у вас появятся диски X: и Y: 
Однако, если такой файл выполнить повторно, команда SUBST выдаст сообщение об ошибке - ведь диски X: и Y: уже существуют. 
Поэтому, желательно обойти выполнение SUBST, если виртуальные диски X: и Y: уже созданы, или удалять их, используя SUBST с параметром -d перед подключением. Попробуем изменить командный файл setletter.bat с использованием команды перехода GOTO, осуществляющей передачу управления строке пакетного файла на указанную метку. 

GOTO метка
В качестве метки используется строка символов, начинающаяся с двоеточия. Сделаем изменения в нашем командном файле, чтобы не возникало сообщений об ошибке:

@ECHO OFF
REM если не существует X: - то перейдем на метку SETX
IF NOT EXIST X:\ GOTO SETX
REM если существует X: - перейдем на проверку наличия Y:
GOTO TESTY
:SETX
IF EXIST G:\flashd1.let SUBST X: G:\
IF EXIST F:\flashd1.let SUBST X: F:\
:TESTY
REM если Y: существует - завершим командный файл.
IF EXIST Y:\ GOTO EXIT
IF EXIST G:\flashd2.let SUBST Y: G:\
IF EXIST F:\flashd2.let SUBST Y: F:\
REM выход из командного файла
:EXIT
exit 

При выполнении измененного таким образом командного файла, сообщение об ошибке при выполнении SUBST исчезнет. 

Конечно, данный пример не может считаться образцом программирования, но главная цель заключается не в написание оптимального командного сценария, а в демонстрации принципов использования меток и переходов. Во всех последующих примерах, насколько это возможно, используется именно такой подход - важна не оптимальность исходного текста, а его максимальная простота для понимания.

Одним из важнейших приемов при написании сложных командных файлов является анализ успешности выполнения конкретной команды или программы. Признаки ошибок при выполнении команд можно отслеживать, анализируя специальную переменную ERRORLEVEL , значение которой формируется при выполнении большинства программ. Обычно ERRORLEVEL равно нулю, если программа завершилась без ошибок и единице - при возникновении ошибки. Могут быть и другие значения, если они предусмотрены в выполняемой программе. 

    В качестве команды в строке командного файла можно использовать также командный файл. Причем, для передачи с возвратом обратно к точке выполнения вызывающего командного файла используется команда CALL. Попробуйте создать командный файл test.bat, следующего содержания:

@ECHO OFF
ECHO Вызов 1.bat
CALL 1.bat
ECHO Возврат.

В этом же каталоге, создайте второй файл под именем 1.bat, содержащий команду 

PAUSE - приостановить выполнение командного файла до нажатия любой клавиши.

@ECHO OFF
pause



При выполнении командного файла test.bat будет выдано на экран сообщение 
Вызов 1.bat
и управление получит командный файл 1.bat с одной единственной командой pause. После начатия клавиши на клавиатуре управление будет возвращено вызвавшему командному файлу на строку "ECHO Возврат." и на экран будет выдано 
Возврат.
Если же в файле test.bat убрать CALL, оставив "1.bat", то , выполнится командный файл 1.bat, и возврат в test.bat выполняться не будет. 

Вызываемый командный файл может создавать переменные и присваивать им определенные значения, которые будут доступны для обработки в вызывающем файле. Попробуйте изменить файл test.bat следующим образом:

@ECHO OFF
ECHO Вызов 1.bat
CALL 1.bat
ECHO Получено из файла %MYFILE% значение MYNUMBER=%MYNUMBER%.

Вызываемый файл 1.bat изменим следующим образом:

@ECHO OFF
SET MYFILE="Very good 1.bat"
SET MYNUMBER=99



Переменные вызываемого файла будут доступны в вызывающем файле.

Кстати, используя передачу управления командному файлу, можно организовать его зацикливание. Попробуйте добавить в конец файла test.bat строку:

CALL test.bat

Выйти из зацикливания командного файла можно по нажатию комбинации CTRL+Break.

Команда CALL может использоваться не только для вызова другого командного файла, для вызова внутренней подпрограммы. В этом случае в качестве аргумента используется не имя внешнего файла, а метка:

call :proc1
....
:proc1
....
exit
....


 

 



 

Примеры командных файлов.



    Использование утилит командной строки и командных файлов нередко позволяют решить многие проблемы связанные с повседневной эксплуатацией компьютерной техники. Большинство системных администраторов и грамотных пользователей продолжают ими пользоваться, несмотря на то, что в Windows проявилось новое, более мощное и современное средство управления системой - WMI(Windows Management Instrumentation) и многофункциональная оболочка пользователя Power Shell. Очевидно, не в последнюю очередь, это обусловлено простотой реализации и достаточной эффективностью командной строки для решения повседневных задач обслуживания системы. Ниже приведены простые примеры с комментариями, которые демонстрируют некоторые возможности и способы применения .cmd и .bat 

 

Своя команда для создания новых файлов.



    В составе операционной системы Windows нет специальной команды для создания нового файла, но без нее можно легко обойтись несколькими способами:

Копирование с клавиатуры в файл 

COPY CON myfile.txt

При выполнении этой команды данные с клавиатуры (стандартное устройство CON - консоль) будут заноситься в файл myfile.txt. Нажатие клавиши F6 или комбинации CTRL-Z завершит вывод.

Перенаправление вывода 

ECHO 1 > myfile.txt

При выполнении этой команды будет создан файл myfile.txt, содержащий символ "1"

Комбинация перенаправления ввода и перенаправления вывода:

COPY CON > myfile.txt < xyz 

При выполнении этой команды, как и в первом случае, используется копирование с консоли в файл, но вместо ручного ввода данных с клавиатуры используется ввод с несуществующего файла (устройства) xyz. Система выдаст сообщение, о том, что такого устройства или файла не существует, но пустой файл myfile.txt будет успешно создан. 

Обычно, для создания пустого файла используется команда копирования из фиктивного устройства nul в файл. Использование устройства nul позволяет обойти стандартные операции ввода-вывода, которые для него реально не выполняются. При выполнении копирования с фиктивного устройства в файл будет создан пустой файл без каких-либо сообщений об ошибке.

COPY NUL myfile.txt

    При работе в командной строке часто приходится создавать новые пустые файлы, поэтому, стоит подготовить свой командный файл (например, с именем nf.bat), а имя нового создаваемого файла передавать ему в качестве параметра при запуске. 

Содержимое файла:

@echo off
REM Создание пустого файла, имя которого задано в строке запуска
if "%1" EQU "" goto error
copy nul %1
goto exit
:error
ECHO ОШИБКА: Необходимо задать имя нового файла !
:exit 

    Для удобства использования, можно поместить этот командный в системный каталог (например, в C:\windows\system32) или любой другой, существующий в путях поиска, задаваемых значением переменной PATH). Теперь, в командной строке, находясь в любом каталоге можно одной командой создавать пустые файлы.

Командная строка:

nf.bat myfile.txt - создать файл с именем myfile.txt в текущем каталоге.
nf.bat C:\myfile.txt - создать файл в корневом каталоге диска C:
nf.bat "%USERPROFILE%\myfile.txt" - создать файл в каталоге профиля текущего пользователя.

Возможность создания файлов в системных каталогах зависит от настроек безопасности системы и прав пользователя, в контексте учетной записи которого выполняется команда. Многие команды могут быть выполнены только пользователем с правами администратора. 

Расширение командного файла (.bat) можно не набирать и команда еще больше упрощается:

nf myfile.txt

В тексте командного файла присутствует проверка, задано ли имя создаваемого файла в командной строке (if "%1%" EQU "" goto error), и если не задано - выводится сообщение об ошибке и командный файл завершает свою работу.

В плане совершенствования функционала, можно добавить в этот командный файл проверку на существование файла с именем, указанным в командной строке и предупреждением пользователя о его возможной перезаписи. 
 

Присвоение съемному диску одной и той же буквы.



    Задача заключается в том, чтобы съемный USB диск (флэш диск) был доступен всегда под одной и той же буквой, независимо от того, на каком компьютере он используется и каким образом он был подключен. Для ее решения воспользуемся уже упоминаемой выше командой SUBST, но реализуем присвоение новой буквы диску с помощью подстановочного значения переменной %0, создаваемой системой при каждом запуске командного файла.

Выберем для съемного диска желаемую букву, например - X. 

Некоторые из переменных окружения, в том числе и переменная %0, принимающая значение пути и имени выполняющегося командного файла, позволяют при определенной модификации с использованием специального признака - символа " ~ ", получить ее частичное значение (расширение переменной). Например, не полный путь файла, а только его имя, или каталог расположения, или букву диска, с которого он был запущен или еще около десятка различных элементов, связанных с подстановочными значениями переменной %0. 

Имя диска, с которого был запущен командный файл доступно как переменная %~d0. 
Теперь создаем командный файл следующего содержания:
@echo off
subst X: %~d0\

что означает - создать виртуальный диск X:, которому сопоставлен логический диск, являющийся частью пути данного командного файла. Если такой файл записать на флэшку, и выбрать присваиваемую букву диска поближе к концу алфавита (чтобы не оказалась занятой другим реальным дисковым устройством) то после его запуска, в системе будет создаваться новый диск всегда под одной и той же буквой. 

Дополнительное представление о подстановочных значениях переменной %0 можно получить из командного файла следующего содержания: 

@echo off
ECHO ОБРАБАТЫВАЕТСЯ ФАЙЛ - %0
ECHO Дата/время создания/изменения командного файла - %~t0
ECHO Путь командного файла - "%~f0"
ECHO Диск командного файла - %~d0
ECHO Каталог командного файла - "%~p0"
ECHO Имя командного файла - %~n0
ECHO Расширение командного файла - %~x0
ECHO Короткое имя и расширение - %~s0
ECHO Атрибуты командного файла - %~a0
ECHO Размер командного файла - %~z0





 

Создание архива, имя которого содержит дату и время.



    Решим следующую задачу - нужно создать архив файлов, находящихся в каталоге C:\Program Files\FAR. Имя архивного файла должно состоять из текущего времени (часы.минуты.секунды - ЧЧ.ММ.СС.rar), и помещен он должен в новый каталог, имя которого должно состоять из текущей даты (день.месяц.год - ДД.ММ.ГГГГ). Для архивирования будем использовать архиватор RAR. Формат запуска для создания архива:

RAR a -r < путь и имя архива > < Путь и имя архивируемых данных > 

a - команда создания архива.
-r - ключ, определяющий архивирование подкаталогов (т.к. в исходной папке есть подкаталоги).

Таким образом, для решения задачи нужно правильно создать имена и пути для RAR. Для чего воспользуемся следующими исходными данными: